// shedevil.txt
//
// - modified basicnpc/changedialog to allow for additional death state scripting
//   and attack back scripting - activates guards...
//
// NOTE: Use only with she-devil npc due to assumptions about where it is fired
//       from and flag settings.
//
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
//
// Memory Cells:
//   Cell 0 - How creature moves.
//	0 - If 0, wander randomly. 
//	1 - Stands still until a target appears.
//	2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//	is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//	creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//	character doesn't talk.
//   Cell 4 - Dialogue node to start with if talk to after a flag is set. If
//	left at 0, char will stop talking.
//   Cell 5,6 - SDF for switching to second dialogue node. If flag not 0, char 
//	will use the node in cell 4, not in cell 3. If both left at 0, char
//	doesn't switch nodes.

begincreaturescript;

variables;

short i, target, choice;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME, 0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1), get_memory_cell(2), 1);

	// set flag - quest was completed by killing her...
	set_flag(50, 9, 1);
	// popup a dialog about it...
	reset_dialog();
	add_dialog_str(0, "With one last blow, you lay low the she-devil.", 0);
	add_dialog_str(1, "As you stare at your fallen foe, you wonder if bloodshed could've been avoided.", 0);
	add_dialog_str(2, "No one will ever know, now that the she-devil is dead.", 0);
	add_dialog_choice(0, "OK");
	choice = run_dialog(1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
		else
			set_target(ME, -1);
	}
	
	// Look for a target, attack it if visible
	if (select_target(ME, 8, 0)) {
		do_attack();
		set_state(3);
	}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		// set attitude of gaurds to hostile also
		if (get_attitude(7) < 10) {
			set_attitude(1001, 10);
			alert_char(1001);
		}
		// now continue with attack back mode
		set_target(ME, who_hit_me());
		do_attack();
		set_state(3);
	}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1, 1, 100) < 40) 
			return_to_start(ME, 1);
	}
	else if (get_memory_cell(0) == 0) {
		fidget(ME, 25);
	}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_attitude(ME) >= 10) {
		print_str("Talking: It doesn't respond.");
		end();
	}
	if (((get_memory_cell(5) == 0) && (get_memory_cell(6) == 0)) ||
	    (get_flag(get_memory_cell(5), get_memory_cell(6)) == 0)) {
		if (get_memory_cell(3) == 0) {
			print_str("Talking: It doesn't respond.");
			end();
		}
		begin_talk_mode(get_memory_cell(3));
	}
	else {
		if (get_memory_cell(4) == 0) {
			print_str("Talking: It doesn't respond.");
			end();
		}
		begin_talk_mode(get_memory_cell(4));
	}
break;
